COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002		ENTRY	MAKTAB,PIXEL,PUTEL
C00004 ENDMK
C⊗;
	ENTRY	MAKTAB,PIXEL,PUTEL
	TITLE	PICSUB
	I←1
	J←2
	K←3
	M←5
	AR←6

	P←17

RETAD:	0

PCLN←←0
PCWD←←1
PCBY←←2
PCBYA←←3
LNWD←←4
LNBY←←5
LNBYA←←6
WDBY←←7
WDBI←←10
BYBI←←11
BPTAB←12
LINTAB←←13

MAKTAB:	POP	P,RETAD
	POP	P,AR
	MOVEI	I,LINTAB(AR)
	HRRM	I,RWLP
	MOVN	I,PCLN(AR)	;USED INTERNALLY TO GENERATE LINE AND
	HRLZ	I,I		;BYTE TABLES
	MOVE	J,AR
	ADD	J,PCLN(AR)
	ADD	J,LNBYA(AR)
	ADDI	J,14
RWLP:	MOVEM	J,LINTAB(I)	;REPLACED BY ACTUAL ADR OF THE LINE TABLE
	ADD	J,LNWD(AR)
	AOBJN	I,RWLP
	
	MOVE	J,BYBI(AR)
	LSH	J,30
	SUBI	J,1
	MOVE	I,BPTAB(AR)
	HRRM	I,COLP
	MOVEM	J,-1(I)
	MOVEI	J,44
	SUB	J,BYBI(AR)
	LSH	J,6
	OR	J,BYBI(AR)
	LSH	J,30
	MOVN	I,LNBYA(AR)
	HRLZ	I,I
COLP:	MOVEM	J,BPTAB(I)	;REPLACED BY ACTUAL ADR OF BYTE TABLE
	IBP	J
	AOBJN	I,COLP
	JRST	@RETAD

PIXEL:	POP	P,RETAD
	POP	P,J
	POP	P,I
	POP	P,AR
	MOVEI	K,LINTAB(AR)
	HRRM	K,LNTB
	MOVE	K,BPTAB(AR)
	HRRM	K,BPTB
LNTB:	MOVE	K,LINTAB(I)
BPTB:	ADD	K,BPTAB(J)
	LDB	1,K
	JRST	@RETAD

PUTEL:	POP	P,RETAD
	POP	P,M
	POP	P,J
	POP	P,I
	POP	P,AR
	MOVEI	K,LINTAB(AR)
	HRRM	K,LNTB1
	MOVE	K,BPTAB(AR)
	HRRM	K,BPTB1
LNTB1:	MOVE	K,LINTAB(I)
BPTB1:	ADD	K,BPTAB(J)
	DPB	M,K
	JRST	@RETAD

	END